智能化控制開關(guān)(有延時防止沖擊智能繼電器開關(guān))

下面是單片機控制程序
delay_time0     equ  180       ;3t
delay_time1     equ  10        ;10s
delay_time2     equ  5         ;5s

led     bit    p1.0
byq     bit    p3.7

jdq0    bit    p1.7
jdq1    bit    p1.6
jdq2    bit    p1.5
jdq3    bit    p1.4
jdq4    bit    p1.3

ic_err  bit    20h.0

use_time0      data 08h
use_time1      data 09h
delay_sum0     data 0ah
delay_sum1     data 0bh

        org     0
        ljmp    reset
        org     3h
        reti
        org     0bh
        ajmp    tim0
        ;reti
        org     13h
        reti
        org     01bh
        reti
        org     23h
        reti

Reset:  mov ie,#00h            ;關(guān)中斷
 clr a
 mov b,a
 mov ip,a
 mov psw,a
 mov pcon,a
 mov scon,a
 mov tcon,a
 mov tmod,a
 mov sp,#07h
 mov p1,#0h
 mov p3,#7fh
 mov dptr,#ResNext     ;中斷清0
 push dpl
 push dph
 reti
ResNext:mov dptr,#ResRam
 push dpl
 push dph
 reti
ResRam: mov r0,#7fh
ResRam0:mov @r0,a              ;內(nèi)存清0
 djnz r0,ResRam0
ResetEnd:

init:   mov     sp,#30h      ;堆棧指針
        mov     tmod,#01h
        mov     ie,#82h

main:   mov     b,#2
        acall   delay       ;調(diào)用延時子程序2秒
        clr     led

        setb    byq         ;開變壓器
        setb    tr0         ;led閃爍開關(guān)

        mov     b,#delay_time0;調(diào)用延時子程序3分鐘
        acall   delay
        setb    jdq0        ;開繼電器1

        mov     b,#delay_time1
        acall   delay
        setb    jdq1        ;開繼電器2

        mov     b,#delay_time1
        acall   delay
        setb    jdq2        ;開繼電器3

        mov     b,#delay_time1
        acall   delay
        setb    jdq3        ;開繼電器4

        mov     b,#delay_time1
        acall   delay
        setb    jdq4        ;開繼電器5

wait:   jb      p3.2,$      ;等待
        mov     b,#3
        acall   delay
        jb      p3.2,wait

        clr     tr0
        clr     led
        mov     ie,#0

        mov     b,#delay_time2
        acall   delay
        clr     jdq4        ;close 1

        mov     b,#delay_time2
        acall   delay
        clr     jdq3        ;close 2

        mov     b,#delay_time2
        acall   delay
        clr     jdq2        ;close 3

        mov     b,#delay_time2
        acall   delay
        clr     jdq1        ;close 4

        mov     b,#delay_time2
        acall   delay
        clr     jdq0        ;close 5

        mov     b,#150
        acall   delay
        mov     b,#150
        acall   delay
        clr     byq         ;close 變壓器

        sjmp    $            ;停止

delay: mov    r6,#0
       mov    r7,#0
delay1:mov    r5,#15
delay0:djnz   r7,$
       djnz   r6,delay0
       djnz   r5,delay0
       djnz   b,delay1        ;當(dāng)b等于1時，延時1秒
       ret

tim0:  mov     th0,#0b1h;     ;24M晶振-10ms
       mov     tl0,#0dfh;     ;20000

         jb      ic_err,tim0_3
         djnz    delay_sum0,tim0_end
         mov     delay_sum0,#100     ;1s     led閃爍頻率
         sjmp    tim0_2
tim0_3:  djnz    delay_sum0,tim0_end
         mov     delay_sum0,#10      ;0.2s   led閃爍頻率
tim0_2:  cpl     led
tim0_end:reti